// Test1.java
public class Test1{
    public static void main(String[] args){
        System.out.print(tt());
    }

    public static int tt(){
        int b = 23;
        try{
            return b = 88;
        }
        finally {
            if(b > 25){
                System.out.println("b > 25 : "+b);
            }
        }
    }
}

Compiled from "Test1.java"
public class Test1 extends java.lang.Object{
public Test1();
  Code:
   0:   aload_0
   1:   invokespecial   #1; //Method java/lang/Object."<init>":()V
   4:   return

public static void main(java.lang.String[]);
  Code:
   0:   getstatic       #2; //Field java/lang/System.out:Ljava/io/PrintStream;
   3:   invokestatic    #3; //Method tt:()I
   6:   invokevirtual   #4; //Method java/io/PrintStream.print:(I)V
   9:   return

public static int tt();
  Code:
   0:   bipush  23      // 将数据23转换为int类型，然后将其压入栈
   2:   istore_0        // 从栈中弹出int类型值，然后将其存到位置为0的局部变量中
                        // 执行int b = 23;

   3:   bipush  88      // 将数据88转换为int类型，然后将其压入栈
   5:   dup             // 复制栈顶部的一个字，然后再将复制内容压入栈
                        // 这里是执行b = 88语句

   6:   istore_0        // 从栈中弹出int类型值，然后将其存到位置为0的局部变量中
                        // 这里存的是88，b = 88语句的执行后b的值

   7:   istore_1        // 从栈中弹出int类型值，然后将其存到位置为1的局部变量中
                        // 这里存的是88，b = 88语句的执行结果，将要被return语句返回的值

   8:   jsr     19      // 把返回地址压入栈，跳转至偏移量指定位置处执行分支操作
                        // 这里先将指令8的偏移地址压入栈，然后跳转到指令19，finally子句的开始

   11:  iload_1         // 将位置为1的int类型局部变量压入栈
                        // 将先前存到位置为1的局部变量中的返回值压入栈

   12:  ireturn         // 从方法中返回int类型的数据
                        // 即try子句中最后的一步操作：return方法tt的的返回值

   13:  astore_2
   14:  jsr     19
   17:  aload_2
   18:  athrow
                        // 指令13－18是针对try子句产生异常的情况，这里不做分析

   19:  astore_3        // 从栈中弹出对象引用，然后将其存到位置为3的局部变量中
                        // finally子句的开始
                        // 这里弹出的是指令8(不发生异常的情况下)中压入栈的返回地址，原因在前面摘抄的文字中已经解释过了

   20:  iload_0         // 将位置为0的int类型局部变量压入栈
   21:  bipush  25      // 将数据25转换为int类型，然后将其压入栈
   23:  if_icmple       51
   26:  getstatic       #2; //Field java/lang/System.out:Ljava/io/PrintStream;
   29:  new             #5; //class StringBuffer
   32:  dup
   33:  invokespecial   #6; //Method java/lang/StringBuffer."<init>":()V
   36:  ldc             #7; //String b > 25 :
   38:  invokevirtual   #8; //Method java/lang/StringBuffer.append:(Ljava/lang/String;)Ljava/lang/StringBuffer;
   41:  iload_0
   42:  invokevirtual   #9; //Method java/lang/StringBuffer.append:(I)Ljava/lang/StringBuffer;
   45:  invokevirtual   #10; //Method java/lang/StringBuffer.toString:()Ljava/lang/String;
   48:  invokevirtual   #11; //Method java/io/PrintStream.println:(Ljava/lang/String;)V
                        // 指令20－48执行if子句，略过，不做分析

   51:  ret     3       // 从子例程中返回到保存在局部变量3中的地址
                        // 呼应指令19，从finally子句转回到try子句
  Exception table:
   from   to  target type
     3    11    13   any
    13    17    13   any

}